Offline Insider Enroll ile desteklenmeyen cihazlara Insider Build nasıl kurulur?

456593 · 1 Eylül 2021

Dikkat! Şimdilik sadece Windows 11 üzerinden yapacağınız yükseltmeler için geçerli!
Bildiğiniz veya bilmediğiniz üzere Microsoft desteklenmeyen cihazlarda artık Insider kurulmasına da izin vermiyor. (TPM desteklemeyenler kuramaz. Sadece CPU'su desteklemeyenler hala kurabiliyor.)
Bkz: Windows 11 Desteklemeyen Bilgisayarlar Artık Insider Programında Güncelleme Almayacak
Telemetri verilerini RPM versiyonda kullanacakları gibi, bu durumda da kullanırlar diye düşünmüştüm fakat çok daha basit bir yöntemle üstesinden geldim.

2019'da kullanıma açılan Offline Insider Enroll isimli program, hesabınız olsa da olmasa da cihazınız desteklense de desteklenmese de Insider buildlerinizi almanızı sağlar.
Github: GitHub - whatever127/offlineinsiderenroll: OfflineInsiderEnroll - A script to enable access to the Windows Insider Program on machines not signed in with Microsoft Account
Program basit bir .bat uzantısıdır. CMD aracılığıyla çalışır.

.bat içeriği tamamen güvenlidir. Anlaşılan o ki sadece birkaç regedit düzenlemeleriyle bu sorun aşılabiliyor.

[CODE title="CMD"]@echo off

::Borrowed from @abbodi1406's scripts
for /f "tokens=6 delims=[]. " %%i in ('ver') do set build=%%i

if %build% LSS 17763 (
echo =============================================================
echo This script is compatible only with Windows 10 RS5 and later.
echo =============================================================
echo.
pause
goto :EOF
)

REG QUERY HKU\S-1-5-19\Environment >NUL 2>&1
IF %ERRORLEVEL% EQU 0 goto :START_SCRIPT

echo =====================================================
echo This script needs to be executed as an administrator.
echo =====================================================
echo.
pause
goto :EOF

:START_SCRIPT
set "scriptver=2.5.0"
set "FlightSigningEnabled=0"
bcdedit /enum {current} | findstr /I /R /C:"^flightsigning *Yes$" >NUL 2>&1
IF %ERRORLEVEL% EQU 0 set "FlightSigningEnabled=1"

:CHOICE_MENU
cls
set "choice="
echo OfflineInsiderEnroll v%scriptver%
echo.
echo 1 - Enroll to Dev Channel
echo 2 - Enroll to Beta Channel
echo 3 - Enroll to Release Preview Channel
echo.
echo 4 - Stop receiving Insider Preview builds
echo 5 - Quit without making any changes
echo.
set /p choice="Choice: "
echo.
if /I "%choice%"=="1" goto :ENROLL_DEV
if /I "%choice%"=="2" goto :ENROLL_BETA
if /I "%choice%"=="3" goto :ENROLL_RP
if /I "%choice%"=="4" goto :STOP_INSIDER
if /I "%choice%"=="5" goto :EOF
goto :CHOICE_MENU

:ENROLL_RP
set "Channel=ReleasePreview"
set "Fancy=Release Preview Channel"
set "BRL=8"
goto :ENROLL

:ENROLL_BETA
set "Channel=Beta"
set "Fancy=Beta Channel"
set "BRL=4"
goto :ENROLL

:ENROLL_DEV
set "Channel=Dev"
set "Fancy=Dev Channel"
set "BRL=2"
goto :ENROLL

:RESET_INSIDER_CONFIG
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Account" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Cache" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\WUMUDCat" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingExternal" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingPreview" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingInsiderSlow" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingInsiderFast" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection" /v AllowTelemetry /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\DataCollection" /v AllowTelemetry /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /v BranchReadinessLevel /f
goto :EOF

:ADD_INSIDER_CONFIG
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Orchestrator" /t REG_DWORD /v EnableUUPScan /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingExternal" /t REG_DWORD /v Enabled /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\WUMUDCat" /t REG_DWORD /v WUMUDCATEnabled /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v EnablePreviewBuilds /d 2 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v IsBuildFlightingEnabled /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v IsConfigSettingsFlightingEnabled /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v TestFlags /d 32 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v RingId /d 11 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v Ring /d "External" /f
rem reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v ContentType /d "Mainline" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v BranchName /d "%Channel%" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Strings" /t REG_SZ /v StickyXaml /d "<StackPanel xmlns="^""http://schemas.microsoft.com/winfx/2006/xaml/presentation"^""><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"">This device has been enrolled to the Windows Insider program using OfflineInsiderEnroll v%scriptver%. If you want to change settings of the enrollment or stop receiving Insider Preview builds, please use the script. <Hyperlink NavigateUri="^""https://github.com/abbodi1406/offlineinsiderenroll/blob/master/readme.md"^"" TextDecorations="^""None"^"">Learn more</Hyperlink></TextBlock><TextBlock Text="^""Applied configuration"^"" Margin="^""0,20,0,10"^"" Style="^""{StaticResource SubtitleTextBlockStyle}"^"" /><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"" Margin="^""0,0,0,5"^""><Run FontFamily="^""Segoe MDL2 Assets"^""></Run> <Span FontWeight="^""SemiBold"^"">%Fancy%</Span></TextBlock><TextBlock Text="^""Channel: %Channel%"^"" Style="^""{StaticResource BodyTextBlockStyle }"^"" /><TextBlock Text="^""Content: Mainline"^"" Style="^""{StaticResource BodyTextBlockStyle }"^"" /><TextBlock Text="^""Telemetry settings notice"^"" Margin="^""0,20,0,10"^"" Style="^""{StaticResource SubtitleTextBlockStyle}"^"" /><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"">Windows Insider Program requires your diagnostic data collection settings to be set to <Span FontWeight="^""SemiBold"^"">Full</Span>. You can verify or modify your current settings in <Span FontWeight="^""SemiBold"^"">Diagnostics & feedback</Span>.</TextBlock><Button Command="^""{StaticResource ActivateUriCommand}"^"" CommandParameter="^""ms-settingsrivacy-feedback"^"" Margin="^""0,10,0,0"^""><TextBlock Margin="^""5,0,5,0"^"">Open Diagnostics & feedback</TextBlock></Button></StackPanel>" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIHiddenElements /d 65535 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIDisabledElements /d 65535 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIServiceDrivenElementVisibility /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIErrorMessageVisibility /d 192 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection" /t REG_DWORD /v AllowTelemetry /d 3 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /t REG_DWORD /v BranchReadinessLevel /d %BRL% /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Strings" /t REG_SZ /v StickyMessage /d "{"^""Message"^"":"^""Device Enrolled Using OfflineInsiderEnroll"^"","^""LinkTitle"^"":"^"""^"","^""LinkUrl"^"":"^"""^"","^""DynamicXaml"^"":"^""<StackPanel xmlns=\\"^""http://schemas.microsoft.com/winfx/2006/xaml/presentation\\"^""><TextBlock Style=\\"^""{StaticResource BodyTextBlockStyle }\\"^"">This device has been enrolled to the Windows Insider program using OfflineInsiderEnroll v%scriptver%. If you want to change settings of the enrollment or stop receiving Insider Preview builds, please use the script. <Hyperlink NavigateUri=\\"^""https://github.com/abbodi1406/offlineinsiderenroll/blob/master/readme.md\\"^"" TextDecorations=\\"^""None\\"^"">Learn more</Hyperlink></TextBlock><TextBlock Text=\\"^""Applied configuration\\"^"" Margin=\\"^""0,20,0,10\\"^"" Style=\\"^""{StaticResource SubtitleTextBlockStyle}\\"^"" /><TextBlock Style=\\"^""{StaticResource BodyTextBlockStyle }\\"^"" Margin=\\"^""0,0,0,5\\"^""><Run FontFamily=\\"^""Segoe MDL2 Assets\\"^""></Run> <Span FontWeight=\\"^""SemiBold\\"^"">%Fancy%</Span></TextBlock><TextBlock Text=\\"^""Channel: %Channel%\\"^"" Style=\\"^""{StaticResource BodyTextBlockStyle }\\"^"" /><TextBlock Text=\\"^""Content: Mainline\\"^"" Style=\\"^""{StaticResource BodyTextBlockStyle }\\"^"" /><TextBlock Text=\\"^""Telemetry settings notice\\"^"" Margin=\\"^""0,20,0,10\\"^"" Style=\\"^""{StaticResource SubtitleTextBlockStyle}\\"^"" /><TextBlock Style=\\"^""{StaticResource BodyTextBlockStyle }\\"^"">Windows Insider Program requires your diagnostic data collection settings to be set to <Span FontWeight=\\"^""SemiBold\\"^"">Full</Span>. You can verify or modify your current settings in <Span FontWeight=\\"^""SemiBold\\"^"">Diagnostics & feedback</Span>.</TextBlock><Button Command=\\"^""{StaticResource ActivateUriCommand}\\"^"" CommandParameter=\\"^""ms-settingsrivacy-feedback\\"^"" Margin=\\"^""0,10,0,0\\"^""><TextBlock Margin=\\"^""5,0,5,0\\"^"">Open Diagnostics & feedback</TextBlock></Button></StackPanel>"^"","^""Severity"^"":0}" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIHiddenElements_Rejuv /d 65534 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIDisabledElements_Rejuv /d 65535 /f
goto :EOF

:ENROLL
echo Applying changes...
call :RESET_INSIDER_CONFIG 1>NUL 2>NUL
call :ADD_INSIDER_CONFIG 1>NUL 2>NUL
bcdedit /set {current} flightsigning yes >NUL 2>&1
echo Done.

echo.
IF %FlightSigningEnabled% NEQ 1 goto :ASK_FOR_REBOOT
pause
goto :EOF

:STOP_INSIDER
echo Applying changes...
call :RESET_INSIDER_CONFIG 1>NUL 2>NUL
bcdedit /deletevalue {current} flightsigning >NUL 2>&1
echo Done.

echo.
IF %FlightSigningEnabled% NEQ 0 goto :ASK_FOR_REBOOT
pause
goto :EOF

:ASK_FOR_REBOOT
set "choice="
echo A reboot is required to finish applying changes.
set /p choice="Would you like to reboot your PC? (y/N) "
if /I "%choice%"=="y" shutdown -r -t 0
goto :EOF[/CODE]

Programı çalıştırdığınızda sizden bir Insider kanalı seçmenizi ister. Dev Channel veya Beta Channel(daha stabil) kullanarak Windows 11'e erişebilirsiniz.
Seçiminizi yaptıktan sonra uygulama sizden bilgisayarınızı başlatmanızı ister.
Yeniden başlattıktan sonra Insider ekranını kontrol edebilirsiniz.

Ayrıca cihazınızda TPM olmadığı için(Sadece Windows 10 kullanıcıları için geçerli) Windows Update üzerinden güncelleme gerçekleştirirken ekrana TPM 2.0 Desteği hatası gelebilir. Bunun çözümü bazı yerlerde vardı fakat tekrarlıyorum, bu çözüm Windows 11'den yeni build'ler alacak olan Insider'lar içindir.

Umarım işinize yaramıştır ve umarım Microsoft daha fazla saçmalıklarına devam etmez. Yoksa Windows 11'in pazar değerinin ne kadar düşük olacağını hayal bile edemiyorum.

456593 · 1 Eylül 2021

MuhammedA dedi:
Hmm bu güncelleme yüklensin bakacağız.

Ayrıca cihazınızda TPM olmadığı için(Sadece Windows 10 kullanıcıları için geçerli) Windows Update üzerinden güncelleme gerçekleştirirken ekrana TPM 2.0 Desteği hatası gelebilir. Bunun çözümü bazı yerlerde vardı fakat tekrarlıyorum, bu çözüm Windows 11'den yeni build'ler alacak olan Insider'lar içindir. Gerisi size kalmış.

MuhammedA · 1 Eylül 2021

Bu uygulamayı Windows 10 üzerinden çalıştırırsanız Windows 10 Insider Preview 21390.2025 güncellemesi gelir ve bu güncelleme Windows 11 Insider kanalına gelmeden önceki en son Windows 10 Insider Preview güncellemesidir. Bu güncellemenin en temel özelliği ise Windows 11 de ki yeni simgelerin Windows 10 da olmasıdır. Dezavantajı ise sadece 1 ay süresi vardır.

456593 · 1 Eylül 2021

MuhammedA dedi:
Bu uygulamayı Windows 10 üzerinden çalıştırırsanız Windows 10 Insider Preview 21390.2025 güncellemesi gelir ve bu güncelleme Windows 11 Insider kanalına gelmeden önceki en son Windows 10 Insider Preview güncellemesidir. Bu güncellemenin en temel özelliği ise Windows 11 de ki yeni simgelerin Windows 10 da olmasıdır. Dezavantajı ise sadece 1 ay süresi vardır.

Eki Görüntüle 1155532

Umarım memnun kalmışsındır. Sızdırılmış Windows 11'e geçiş yaparsan, oradan Windows 11 Preview alabilirsin. Denedim.

MuhammedA · 1 Eylül 2021

456593 dedi:
Umarım memnun kalmışsındır. Sızdırılmış Windows 11'e geçiş yaparsan, oradan Windows 11 Preview alabilirsin. Denedim.

Orijinal ISO'da çalışıyor mu? Yani Microsoft'un yayınladığı?

456593 · 1 Eylül 2021

MuhammedA dedi:
Orijinal ISO'da çalışıyor mu? Yani Microsoft'un yayınladığı?

Tabi. Windows 11'e TPM Bypass yaparak geçiş yaparsanız, bu programı kullanarak ilerde çıkacak build'leri kullanabilirsiniz.

MuhammedA · 2 Eylül 2021

456593 dedi:
Tabi. Windows 11'e TPM Bypass yaparak geçiş yaparsanız, bu programı kullanarak ileride çıkacak Build'leri kullanabilirsiniz.

Böyle oldu.

456593 · 2 Eylül 2021

MuhammedA dedi:
Böyle oldu.

Eki Görüntüle 1155593

Program içerisinden Insider programından çıkış yapıp, tekrar giriş yapar mısınız? Büyük ihtimalle işleminiz başarılı.

MuhammedA · 2 Eylül 2021

456593 dedi:
Program içerisinden Insider programından çıkış yapıp, tekrar giriş yapar mısınız? Büyük ihtimalle işleminiz başarılı.

Oldu.

456593 · 26 Eylül 2021

26.09.2021 Microsoft'un UIBranch register'ını değiştirmesiyle beraber taktik fixlendi.

netkit · 15 Nisan 2022

Selamlar;
Güncelleme alabilmek için yeni bir yöntem var mı?

Offline Insider Enroll ile desteklenmeyen cihazlara Insider Build nasıl kurulur?

Ayrıntılı düzenleme

Dosya Ekleri

456593

Hectopat

MuhammedA

Kilopat

456593

Hectopat

MuhammedA

Kilopat

456593

Hectopat

MuhammedA

Kilopat

456593

Hectopat

MuhammedA

Kilopat

456593

Hectopat

netkit

Decapat

Benzer konular