Rehber Dism ile Offline / Online güncelleme entegrasyonu

Microsoft'un düzenli olarak yayınladığı güncellemeleri sisteme kurmak güvenlik, stabilite ve güncel kalmak açısından son derece önemlidir. Online sistemlerde Windows Update üzerinden güncelleştirmeler rahat bir şekilde yüklenebilmektedir. Ancak bazen sorunlar çıkarabiliyor ve güncelleme dosyalarını manuel indirip kurmamız gerekiyor. Msi uzantılı bir güncelleme dosyası indirdiyseniz program kurar gibi kurabilirsiniz. Ancak .Cab uzantılı güncelleme dosyasını kurmak için Dism komutlarına ihtiyaç vardır.
Online sistemlerde Dism ile update işlemini kullanmak çok rastlanılan bir olay değildir. Ancak Offline sistemlere güncelleme yükleme işlemi güncel bir ISO oluşturmak için çok önemlidir ve buradaki en önemli araç Dism'dir. İndirilen Windows.iso dosyasının durumuna bağlı olarak güncelleştirmeler bazen birkaç tane bazen yüzlerce olabiliyor. Dism komutlarını bir kaç güncelleme için düzenleyip .bat dosyası hazırlamak rahat olabilir ancak yüzlerce güncelleme var ise bunlar nasıl düzenlenecek ve yükletilecek. Konunun detaylarına hakim olmayanlar için yükleme komut dosyası oluşturmak tam bir işkence haline gelebilir. Tam da bu sebepten ötürü bu işlemi bizim için basit bir şekilde halledecek komut dosyası hazırladım. Online sistemlerde sadece Update dosyalarını attığınız klasörün yolunu kopyala yapıştır yapmanız yeterli. Offline sistemlerde Update klasörü ve İmajın çıkarıldığı klasör yolunu kopyala yapıştır yapmak yeterli oluyor. Sonra kaç tane güncelleme var ise hepsini otomatik yüklüyor ve mümkünse kalıntıları temizliyor. Mümkünse ile ilgili bölümü Offline güncelleme bölümünde detaylıca anlattım.

Uyarı: Bat dosyasına vereceğiniz klasör yollarında Türkçe harf ve boşluk kullanmamaya özen gösterin. Hata alırsanız büyük bir ihtimalle bu sebepten ötürü hata alırsınız. Ayırca klasör yollarını "C:\Update" bu şekilde tırnak arasını asla almayın. OgnitorenKs.Dism.bat içerisinde örneklerde nasıl olacağını belirttim zaten.

İhtiyaç duyulacaklar

• OgnitorenKs.Dism.bat
• WHDownloader (Güncelleştirmeleri toplu indirmek istiyorsanız bu programı kullananın)
  • Sürprizbozan: WHDownloader Nasıl Kullanılır

    [*]Alıntı:Win toolkit ile Windows güncellemelerini entegre edelim
    [*]

    

    
    
    [*]

1 - Offline sistemlere DISM ile güncelleme yükleme nasıl yapılır?
Bu yöntemle yüklenen güncellemeler uzun sürebilir. Temiz bir imaj için en iyi güncelleme yükleme yöntemidir. Bu yöntem bize güncelleme yükleme işleminden sonra kalıntıları temizleme imkanı vermektedir.

• Windows 8.1 sürümlerinde yaptığım testlerde güncellemelerin büyük bölümü yükleme işleminden sonra temizlik işlemine izin vermemektedir. Temizlenmeyen bu artıklar Sysprep yöntemiyle yüklenip temizlenip yeniden imaj alınması gerekmektedir. Bu konuda da rehber hazırlayacağım.
• Windows 10’da .Net Frework 3.5 güncellemesi eklendiğinde temizlik işlemine izin vermemektedir.

Dism yöntemiyle güncelleme ekleyip temizleme işlemini başarılı bir şekilde tamamlarsak imaj boyutu artmamaktadır. NTLite ile sistem üzerinde düzenleme yaparken önce güncelleştirmeleri Dism ile yükleyip daha sonra düzenleme yapınız.

1.1 - Eksik güncelleştirmelerin tespiti ve yüklemesi nasıl yapılır?
Offline sistemlerde güncellemeleri tespit etmek için NTLite programına ihtiyacımız var.
NTLite ile imajı bağladıktan sonra;

1. Güncellemeler
2. Ekle
3. En son çevrimiçi güncellemeler
4. "Sıraya Al" (Bu bölümde eksik güncelleştirmeler otomatik seçili olur).
5. Güncelleştirme dosyalarının üzerine sırasıyla sağ tıklayın
6. "Web indirmeyi aç" seçeneğini seçin.
7. Açılan Web sayfasından Windows sürümünüzle uygun olan güncelleştirme dosyasını indirin.
8. İndirilen güncelleştirme dosyalarını Update isminde klasöre taşıyınız.
9. NTLite > Kaynak > İşlem yaptığınız Windows sürümüne sağ tıklayın > "Bağlama dizinini keşfet" seçeneğini seçin. Açılan klasör İmaj klasörüdür. Bat dosyası sizden bu yolu isteyince kopyala yapıştır yapın.
10. NTLite kapatın. Çıkan uyarıda "Evet" seçin. OgnitorenKs.Dism.bat dosyasını açın ve 2 rakamını tuşlayınız.
11. İlk olarak, Update klasör yolunu isteyecek. Kopyala yapıştır yapın.
12. İkinci olarak İmaj yolunu isteyecek 9. adımda açtığımız klasör yolunu yapıştırın.
13. İşlem bitince "Anamenüye dönmek için herhangi bir tuşa basınız" yazısı çıkacaktır.

2 - Online sistemlere DISM ile güncelleme yükleme nasıl yapılır?

1. Online sistemlerde Windows Update ile yüklemede sorun yaşadığınız güncelleştirme dosyasını Microsoft Update Catalog sitesinden güncelleştirme ismiyle aratarak sisteminize uygun olanı indirin.
2. İndirilen güncelleştirme dosyalarını Update isminde klasöre taşıyın.
3. OgnitorenKs.Dism.bat dosyasını açın ve 3 rakamını tuşlayın.
4. Update dosyalarını içeren klasör yolunu kopyala yapıştır yapınız.
5. İşlem bitince "Anamenüye dönmek için herhangi bir tuşa basınız" yazısı çıkacaktır.

[CODE title="OgnitorenKs.Dism.bat dosyasının içeriği"]echo off
cls
title OgnitorenKs Dism Update

net session >NUL 2>&1|| powershell Start-Process '%0' -Verb RunAs&& exit /b|| exit /b

setlocal
call :setESC

:anamenu
cls
mode con cols=53 lines=12
echo ===================================================
echo %ESC%[7mOgnitorenKs Dism Toolbax%ESC%[0m
echo ===================================================
echo %ESC%[92m1.%ESC%%ESC%[33m WIM / ESD Okuyucu%ESC%[0m
echo %ESC%[92m2.%ESC%%ESC%[33m Dism Update / Offline%ESC%[0m
echo %ESC%[92m3.%ESC%%ESC%[33m Dism Update / Online%ESC%[0m
echo %ESC%[92m0.%ESC%%ESC%[91m Çıkış%ESC%[0m
echo ---------------------------------------------------

set /p anamenu= %ESC%[92m Yapmak istediğiniz işlem : %ESC%[0m
if %anamenu%==1 GOTO wimreader
if %anamenu%==2 GOTO dismupdateoffline
if %anamenu%==3 GOTO dismupdateonline
if %anamenu%==0 GOTO exit
else
goto anamenu

:wimreader
cls
mode con cols=85 lines=20
echo ===================================================================================
echo %ESC%[7mWIM / ESD Reader \OgnitorenKs%ESC%[0m
echo ===================================================================================
echo %ESC%[96m %ESC%[0m
echo %ESC%[96m Örnek:%ESC%%ESC%[33m "C:\Windows10\sources\install.wim"%ESC%[0m
set /p ogren=%ESC%[97m %ESC%%ESC%[92m Wim dosya yolunu yazın:%ESC%[0m
if %ogren%==0 GOTO anamenu
mode con cols=85 lines=45
dism /Get-WimInfo /WimFile:%ogren%
dism /Get-WimInfo /WimFile:%ogren% > %systemdrive%\Users\%username%\desktop\WimReaderOgnitorenKs.txt
echo %ESC%[96m %ESC%[0m
FOR /F "tokens=3" %%a IN ('dism /Get-WimInfo /WimFile:%ogren% ^| FIND "Index"') DO dism /Get-WimInfo /WimFile:%ogren% /index:%%a >> %systemdrive%\Users\%username%\desktop\WimReaderOgnitorenKs.txt

echo %ESC%[97mMasaüstü\WimReaderOgnitorenKs.txt%ESC%%ESC%[92m dosyasına bakınız.%ESC%[0m
pause
goto anamenu

:dismupdateoffline
cls
mode con cols=90 lines=40
title DISM UPDATE OFFLİNE /OgnitorenKs
echo ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
echo %ESC%[96m Örnek:%ESC%%ESC%[33m C:\Users\OgnitorenKs\Desktop\Update%ESC%[0m
set /p guncellemeekle=%ESC%[97m %ESC%%ESC%[92m Güncellemelerin bulunduğu klasör yolu:%ESC%[0m
if %guncellemeekle%==0 GOTO anamenu
echo ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
echo %ESC%[96m Örnek:%ESC%%ESC%[33m D:\NTLite\1\NLTmpMnt01%ESC%[0m
set /p ntyol2=%ESC%[97m %ESC%%ESC%[92m İmaj klasör yolu:%ESC%[0m
if %ntyol2%==0 GOTO anamenu

for /f %%i in ('"dir /b %guncellemeekle%\*"') do DISM /Image:%ntyol2% /add-package /packagepath="%guncellemeekle%\%%i"
DISM /Image:%ntyol2% /Cleanup-Image /StartComponentCleanup

echo %ESC%[92m Ana Menüye dönmek için herhangi bir tuşa basınız.%ESC%[0m
pause
goto anamenu

:dismupdateonline
cls
mode con cols=90 lines=40
title DISM UPDATE ONLİNE /OgnitorenKs
echo ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
echo %ESC%[96m Örnek:%ESC%%ESC%[33m C:\Users\OgnitorenKs\Desktop\Update%ESC%[0m
set /p guncellemeekle2=%ESC%[97m %ESC%%ESC%[92m Güncellemelerin bulunduğu klasör yolu:%ESC%[0m
if %guncellemeekle2%==0 GOTO anamenu

for /f %%i in ('"dir /b %guncellemeekle2%\*"') do DISM /Online /add-package /packagepath="%guncellemeekle2%\%%i"
DISM /Online /Cleanup-Image /StartComponentCleanup

echo %ESC%[92m Ana Menüye dönmek için herhangi bir tuşa basınız.%ESC%[0m
pause
goto anamenu

:setESC
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
set ESC=%%b
exit /B 0
)
exit /B 0[/CODE]

enginbey8108 dedi:

@OgnitorenKs günaydın ustam ne güncelleme otomatik kurmadı bile Windows kurulumdan sonra otomatik kurması için
@OgnitorenKs ustam hep ben başarısız format attım herkes beni kandırıyor.

Genişletmek için tıkla...

Yapamıyorsanız, yapacağım bir şey yok. Demekki bu tarz işlemler size ağır geliyor. Nasıl yapacağınızı dosyaları hazırlayarak anlattım. Konu açın ve yardımcı olabilecek birilerini bulun.
Toolbox güncellenmiştir.

• Readme ve License dosyalarını ekledim. Detaylı tüm bilgi içerisinde yer almaktadır.
• Arayüz ekranı büyütüldü.
• Yönetici yetkisi artık otomatik alınmayacaktır. Sağ-Tık yönetici olarak çalıştırın, yoksa uyarı verecektir.
• "1. WIM / ESD Okuyucu" bölümü güncellendi. Artık txt içine basmak yerine install.wim veya install.esd dosyas içeriğinin ilgili bölümlerini gösterecek. Görseller aşağıda.
• Toolbox klasörü içerisine Update klasörü açıldı. Güncelleme dosyalarını buraya atarak yükletebilirsiniz.